閱讀(6.1k) 書簽贊(0) 我要糾錯

AWK 內(nèi)置函數(shù)

2022-04-22 10:20 更新

內(nèi)置函數(shù)

AWK 為程序開發(fā)者提供了豐富的內(nèi)置函數(shù)。這一章節(jié)會講解 AWK 提供的算術(shù)函數(shù)、字符串操作函數(shù)、時間操作相關(guān)的函數(shù)、位操作函數(shù)以及其它各種各樣的函數(shù)。

算術(shù)函數(shù)

AWK 提供了如下的內(nèi)置算術(shù)運算函數(shù)：

atan2(y,x)

該函數(shù)返回正切值 y/x 的角度值，角度以弧度為單位。示例如下：

[jerry]$ awk 'BEGIN {
  PI = 3.14159265
  x = -10
  y = 10
  result = atan2 (y,x) * 180 / PI;

  printf "The arc tangent for (x=%f, y=%f) is %f degrees\n", x, y, result
}'

執(zhí)行上面的命令得到如下結(jié)果：

The arc tangent for (x=-10.000000, y=10.000000) is 135.000000 degrees

cos(expr)

該函數(shù)返回 expr 的余弦值，輸入?yún)?shù)以弧度為單位。示例如下：

[jerry]$ awk 'BEGIN {
  PI = 3.14159265
  param = 60
  result = cos(param * PI / 180.0);

  printf "The cosine of %f degrees is %f.\n", param, result
}'

執(zhí)行上面的命令得到如下的結(jié)果：

The cosine of 60.000000 degrees is 0.500000.

exp(expr)

此函數(shù)返回自然數(shù) e 的 expr 次冪。

[jerry]$ awk 'BEGIN {
  param = 5
  result = exp(param);

  printf "The exponential value of %f is %f.\n", param, result
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

The exponential value of 5.000000 is 148.413159.

int(expr)

此函數(shù)返回數(shù)值 expr 的整數(shù)部分。示例如下：

[jerry]$ awk 'BEGIN {
  param = 5.12345
  result = int(param)

  print "Truncated value =", result
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Truncated value = 5

log(expr)

此函數(shù)計算 expr 自然對數(shù)。

[jerry]$ awk 'BEGIN {
  param = 5.5
  result = log (param)

  printf "log(%f) = %f\n", param, result
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

log(5.500000) = 1.704748

rand

rand 函數(shù)返回一個大于等于 0 小于 1 的隨機數(shù) N（0<= N < 1）。示例如下：

[jerry]$ awk 'BEGIN {
  print "Random num1 =" , rand()
  print "Random num2 =" , rand()
  print "Random num3 =" , rand()
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Random num1 = 0.237788
Random num2 = 0.291066
Random num3 = 0.845814

sin(expr)

正弦函數(shù)返回角度 expr 的正弦值，角度以弧度為單位。示例如下：

[jerry]$ awk 'BEGIN {
  PI = 3.14159265
  param = 30.0
  result = sin(param * PI /180)

  printf "The sine of %f degrees is %f.\n", param, result
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

The sine of 30.000000 degrees is 0.500000.

sqrt(expr)

此函數(shù)計算 expr 的平方根。

[jerry]$ awk 'BEGIN {
  param = 1024.0
  result = sqrt(param)

  printf "sqrt(%f) = %f\n", param, result
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

sqrt(1024.000000) = 32.000000

srand([expr])

此函數(shù)使用種子值生成隨機數(shù)，數(shù)值　expr 作為隨機數(shù)生成器的種子值。如果沒有指定 expr 的值則函數(shù)默認(rèn)使用當(dāng)前系統(tǒng)時間作為種子值。

[jerry]$ awk 'BEGIN {
  param = 10

  printf "srand() = %d\n", srand()
  printf "srand(%d) = %d\n", param, srand(param)
}'

執(zhí)行上面的命令得到如下的結(jié)果：

srand() = 1
srand(10) = 1417959587

字符串函數(shù)

AWK 提供了下面所示的字符串操作函數(shù)：

asort(arr,[, d [,how] ])

asort 函數(shù)使用 GAWK 值比較的一般規(guī)則排序 arr 中的內(nèi)容，然后用以 1 開始的有序整數(shù)替換排序內(nèi)容的索引。

[jerry]$ awk 'BEGIN {
    arr[0] = "Three"
    arr[1] = "One"
    arr[2] = "Two"

    print "Array elements before sorting:"
    for (i in arr) {
        print arr[i]
    }

    asort(arr)

    print "Array elements after sorting:"
    for (i in arr) {
        print arr[i]
    }
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Array elements before sorting:
Three
One
Two
Array elements after sorting:
One
Three
Two

asorti(arr,[, d [,how] ])

asorti 函數(shù)的行為與 asort 函數(shù)的行為很相似，二者的差別在于 aosrt 對數(shù)組的值排序，而 asorti 對數(shù)組的索引排序。

[jerry]$ awk 'BEGIN {
    arr["Two"] = 1
    arr["One"] = 2
    arr["Three"] = 3

    asorti(arr)

    print "Array indices after sorting:"
    for (i in arr) {
        print arr[i]
    }
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Array indices after sorting:
One
Three
Two

gsub(regexp, replacement [, target])

gsub 是全局替換( global substitution )的縮寫。它將出現(xiàn)的子串 regexp 替換為 replacement 。第三個參數(shù) target 是可選的，默認(rèn)值為 $0，表示在整個輸入記錄中搜索子串。

[jerry]$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    gsub("World", "Jerry", str)

    print "String after replacement = " str
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

String before replacement = Hello, World
String after replacement = Hello, Jerry

index(str,sub)

index 函數(shù)用于檢測字符串 sub 是否是 str 的子串。如果 sub 是 str 的子串，則返回子串 sub 在字符串 str 的開始位置；若不是其子串，則返回 0。str 的字符位置索引從 1 開始計數(shù)。

[jerry]$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = index(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Substring "Two" found at 5 location.

length(str)

length 函數(shù)返回字符串的長度。

[jerry]$ awk 'BEGIN {
    str = "Hello, World !!!"

    print "Length = ", length(str)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Length = 16

match(str, regex)

在字符串中搜索與正則表達(dá)式regexp匹配的最長、最左邊的子字符串，并返回該子字符串開始的字符位置（索引）。如果匹配失敗則返回0。

[jerry]$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = match(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Substring "Two" found at 5 location.

split(str, arr,regex)

split 函數(shù)使用正則表達(dá)式 regex 分割字符串 str。分割后的所有結(jié)果存儲在數(shù)組 arr 中。如果沒有指定 regex 則使用 FS 切分。

[jerry]$ awk 'BEGIN {
    str = "One,Two,Three,Four"

    split(str, arr, ",")

    print "Array contains following values"

    for (i in arr) {
        print arr[i]
    }
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Array contains following values
One
Two
Three
Four

sprintf(format,expr-list)

sprintf 函數(shù)按指定的格式（ format ）將參數(shù)列表 expr-list 構(gòu)造成字符串然后返回。

[jerry]$ awk 'BEGIN {
    str = sprintf("%s", "Hello, World !!!")

    print str
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Hello, World !!!

strtonum(str)

strtonum 將字符串 str 轉(zhuǎn)換為數(shù)值。如果字符串以 0 開始，則將其當(dāng)作八進(jìn)制數(shù)；如果字符串以 0x 或 0X 開始，則將其當(dāng)作十六進(jìn)制數(shù)；否則，將其當(dāng)作浮點數(shù)。

[jerry]$ awk 'BEGIN {
    print "Decimal num = " strtonum("123")
    print "Octal num = " strtonum("0123")
    print "Hexadecimal num = " strtonum("0x123")
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Decimal num = 123
Octal num = 83
Hexadecimal num = 291

sub(regex,sub,string)

sub 函數(shù)執(zhí)行一次子串替換。它將第一次出現(xiàn)的與 regex 匹配的子串用 sub 替換。第三個參數(shù)是可選的，默認(rèn)為 $0。

[jerry]$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    sub("World", "Jerry", str)

    print "String after replacement = " str
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

String before replacement = Hello, World
String after replacement = Hello, Jerry

substr(str, start, l)

substr 函數(shù)返回 str 字符串中從第 start 個字符開始長度為 l 的子串。如果沒有指定 l 的值，返回 str 從第 start 個字符開始的后綴子串。

[jerry]$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Substring = Hello

tolower(str)

此函數(shù)將字符串 str 中所有大寫字母轉(zhuǎn)換為小寫字母然后返回。注意，字符串 str 本身并不被改變。

[jerry]$ awk 'BEGIN {
    str = "HELLO, WORLD !!!"

    print "Lowercase string = " tolower(str)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Lowercase string = hello, world !!!

toupper(str)

此函數(shù)將字符串 str 中所有小寫字母轉(zhuǎn)換為大寫字母然后返回。注意，字符串 str 本身不被改變。

[jerry]$ awk 'BEGIN {
    str = "hello, world !!!"

    print "Uppercase string = " toupper(str)
}'

執(zhí)行上面命令可以得到如下的結(jié)果：

Uppercase string = HELLO, WORLD !!!

時間函數(shù)

AWK 提供了如下的內(nèi)置時間函數(shù)：

systime

此函數(shù)返回從 Epoch 以來到當(dāng)前時間的秒數(shù)（在 POSIX 系統(tǒng)上，Epoch 為1970-01-01 00:00:00 UTC）。

[jerry]$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " systime()
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Number of seconds since the Epoch = 1418574432

mktime(dataspec)

此函數(shù)將字符串 dataspec 轉(zhuǎn)換為與 systime 返回值相似的時間戳。 dataspec 字符串的格式為 YYYY MM DD HH MM SS。

[jerry]$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " mktime("2014 12 14 30 20 10")
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Number of seconds since the Epoch = 1418604610

strftime([format [, timestamp[, utc-flag]]])

此函數(shù)根據(jù) format 指定的格式將時間戳 timestamp 格式化。

[jerry]$ awk 'BEGIN {
    print strftime("Time = %m/%d/%Y %H:%M:%S", systime())
}'

執(zhí)行上面的的命令可以得到如下的結(jié)果：

Time = 12/14/2014 22:08:42

下面是 AWK 支持的不同的日期格式說明：

SN	描述
%a	星期縮寫(Mon-Sun)。
%A	星期全稱（Monday-Sunday）。
%b	月份縮寫（Jan）。
%B	月份全稱（January）。
%c	本地日期與時間。
%C	年份中的世紀(jì)部分，其值為年份整除100。
%d	十進(jìn)制日期(01-31)
%D	等價于 %m/%d/%y.
%e	日期，如果只有一位數(shù)字則用空格補齊
%F	等價于 %Y-%m-%d，這也是 ISO 8601 標(biāo)準(zhǔn)日期格式。
%g	ISO8610 標(biāo)準(zhǔn)周所在的年份模除 100（00-99)。比如，1993 年 1 月 1 日屬于 1992 年的第 53 周。所以，雖然它是 1993 年第 1 天，但是其　ISO8601 標(biāo)準(zhǔn)周所在年份卻是 1992。同樣，盡管 1973 年 12 月 31 日屬于 1973 年但是它卻屬于 1994 年的第一周。所以 1973 年 12 月 31 日的 ISO8610　標(biāo)準(zhǔn)周所在的年是 1974 而不是 1973。
%G	ISO 標(biāo)準(zhǔn)周所在年份的全稱。
%h	等價于 %b.
%H	用十進(jìn)制表示的 24 小時格式的小時(00-23)
%I	用十進(jìn)制表示的 12 小時格式的小時（00-12）
%j	一年中的第幾天（001-366）
%m	月份（01-12）
%M	分鐘數(shù)（00-59)
%n	換行符 (ASCII LF)
%p	十二進(jìn)制表示法（AM/PM）
%r	十二進(jìn)制表示法的時間（等價于 %I:%M:%S %p）。
%R	等價于 %H:%M。
%S	時間的秒數(shù)值（00-60）
%t	制表符 (tab)
%T	等價于 %H:%M:%S。
%u	以數(shù)字表示的星期(1-7),1 表示星期一。
%U	一年中的第幾個星期（第一個星期天作為第一周的開始），00-53
%V	一年中的第幾個星期（第一個星期一作為第一周的開始），01-53。
%w	以數(shù)字表示的星期（0-6），0表示星期日。
%W	十進(jìn)制表示的一年中的第幾個星期（第一個星期一作為第一周的開始），00-53。
%x	本地日期表示
%X	本地時間表示
%y	年份模除 100。
%Y	十進(jìn)制表示的完整年份。
%z	時區(qū)，表示格式為+HHMM（例如，格式要求生成的 RFC 822或者 RFC 1036 時間頭）
%Z	時區(qū)名稱或縮寫，如果時區(qū)待定則無輸出。

位操作函數(shù)

AWK 提供了如下的內(nèi)置的位操作函數(shù)：

and

執(zhí)行位與操作。

[jerry]$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d AND %d) = %d\n", num1, num2, and(num1, num2)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

(10 AND 6) = 2

compl

按位求補。

[jerry]$ awk 'BEGIN {
    num1 = 10

    printf "compl(%d) = %d\n", num1, compl(num1)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

compl(10) = 9007199254740981

lshift

左移位操作。

[jerry]$ awk 'BEGIN {
    num1 = 10

    printf "lshift(%d) by 1 = %d\n", num1, lshift(num1, 1)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

lshift(10) by 1 = 20

rshift

向右移位操作。

[jerry]$ awk 'BEGIN {
    num1 = 10

    printf "rshift(%d) by 1 = %d\n", num1, rshift(num1, 1)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

rshift(10) by 1 = 5

or

按位或操作。

[jerry]$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d OR %d) = %d\n", num1, num2, or(num1, num2)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

(10 OR 6) = 14

xor

按位異或操作。

[jerry]$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d XOR %d) = %d\n", num1, num2, xor(num1, num2)
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

(10 bitwise xor 6) = 12

其它函數(shù)

其它函數(shù)中主要包括:

close(expr)

關(guān)閉管道的文件。

[jerry]$ awk 'BEGIN {
    cmd = "tr [a-z] [A-Z]"
    print "hello, world !!!" |& cmd
    close(cmd, "to")
    cmd |& getline out
    print out;
    close(cmd);
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

HELLO, WORLD !!!

腳本的內(nèi)容看上去很神秘嗎？讓我們來揭開它神秘的面紗。

第一條語句 cmd = "tr [a-z] [A-Z]" 在　AWK 中建立了一個雙向的通信通道。
第二條語句 print 為 tr 命令提供輸入。&| 表示雙向通信。
第三條語句 close(cmd, "to") 完成執(zhí)行后關(guān)閉 to 進(jìn)程。
第四條語句 cmd |& getline out 使用 getline 函數(shù)將輸出存儲到 out 變量中。
接下來的輸出語句打印輸出的內(nèi)容，最后 close 函數(shù)關(guān)閉 cmd。

delete

delete 被用于從數(shù)組中刪除元素。下面的例子演示了如何使用 delete：

[jerry]$ awk 'BEGIN {
    arr[0] = "One"
    arr[1] = "Two"
    arr[2] = "Three"
    arr[3] = "Four"

    print "Array elements before delete operation:"
    for (i in arr) {
        print arr[i]
    }

    delete arr[0]
    delete arr[1]

    print "Array elements after delete operation:"
    for (i in arr) {
        print arr[i]
    }
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Array elements before delete operation:
One
Two
Three
Four

Array elements after delete operation:
Three
Four

exit

該函數(shù)終止腳本執(zhí)行。它可以接受可選的參數(shù) expr 傳遞 AWK 返回狀態(tài)。示例如下：

[jerry]$ awk 'BEGIN {
    print "Hello, World !!!"

    exit 10

    print "AWK never executes this statement."
}'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Hello, World !!!

flush

flush 函數(shù)用于刷新打開文件或管道的緩沖區(qū)。使用方法如下：

fflush([output-expr])

如果沒有提供 output-expr，fflush 將刷新標(biāo)準(zhǔn)輸出。若 output-epxr 是空字符串 ("")，fflush 將刷新所有打開的文件和管道。

getline

getline 函數(shù)讀入下一行。示例中使用 getline 從文件 marks.txt 中讀入一行并輸出：

[jerry]$ awk '{getline; print $0}' marks.txt

執(zhí)行上面的命令可以得到如下的結(jié)果：

2)  Rahul   Maths   90
4)  Kedar   English 85
5)  Hari    History 89

腳本看似工作正常，但是第一行去哪兒了呢？讓我們理一下整個過程。剛啟動時，AWK 從文件 marks.txt 中讀入一行存儲到變量 $0 中。在下一條語句中，我們使用 getline 讀入下一行。因此 AWK 讀入第二行并存儲到 $0 中。最后，AWK 使用 print 輸出第二行的內(nèi)容。這個過程一直到文件結(jié)束。

next 停止處理當(dāng)前記錄，并且進(jìn)入到下一條記錄的處理過程。下面的例子中，當(dāng)模式串匹配成功后程序并不執(zhí)行任何操作：

[jerry]$ awk '{if ($0 ~/Shyam/) next; print $0}' marks.txt

執(zhí)行上面的命令可以得到如下的結(jié)果：

1)  Amit    Physics 80
2)  Rahul   Maths   90
4)  Kedar   English 85
5)  Hari    History 89

nextfile

nextfile 停止處理當(dāng)前文件，從下一個文件第一個記錄開始處理。下面的的例子中，匹配成功時停止處理第一個文件轉(zhuǎn)而處理第二個文件：
首先創(chuàng)建兩個文件。 file1.txt 內(nèi)容如下:

file1:str1
file1:str2
file1:str3
file1:str4

文件 file2.txt 內(nèi)容如下：

file2:str1
file2:str2
file2:str3
file2:str4

現(xiàn)在我們來測試 nextfile 函數(shù)。

[jerry]$ awk '{ if ($0 ~ /file1:str2/) nextfile; print $0 }' file1.txt file2.txt

執(zhí)行上面的命令可以得到如下的結(jié)果：

file1:str1
file2:str1
file2:str2
file2:str3
file2:str4

return

return 用于從用戶自定義的函數(shù)中返回值。請注意，如果沒有指定返回值，那么的返回值是未定義的。下面的例子演示了 return 的使用方法：
首先，創(chuàng)建文件 functions.awk，內(nèi)容如下：

function addition(num1, num2)
{
    result = num1 + num2

    return result
}

BEGIN {
    res = addition(10, 20)
    print "10 + 20 = " res
}

執(zhí)行上面的命令可以得到如下的結(jié)果：

10 + 20 = 30

system

system 函數(shù)可以執(zhí)行特定的命令然后返回其退出狀態(tài)。返回值為 0 表示命令執(zhí)行成功；非 0 表示命令執(zhí)行失敗。下面的示例中執(zhí)行 Date 顯示當(dāng)前的系統(tǒng)時間，然后輸出命令的返回狀態(tài)：

[jerry]$ awk 'BEGIN { ret = system("date"); print "Return value = " ret }'

執(zhí)行上面的命令可以得到如下的結(jié)果：

Sun Dec 21 23:16:07 IST 2014
Return value = 0

以上內(nèi)容是否對您有幫助：

← AWK 循環(huán)

AWK 用戶自定義函數(shù) →

寫筆記

我要補充